import_code("/home/me/h/libs/list.src")
import_code("/home/me/h/libs/disk.src")
import_code("/home/me/h/libs/nmap.src") // exports Nmap, Service
import_code("/home/me/h/libs/scan.src") // exports Scan
import_code("/home/me/h/libs/json.src") // exports Json
import_code("/home/me/h/src/rndIP.src") // exports rnd_ip
import_code("/home/me/h/src/docDB.src") // exports DocDB
import_code("/home/me/h/libs/passwords.src")
import_code("/home/me/h/src/machine.src") // exports Machine, MachineService, depends on Scan, Nmap	, Json, DocDB
import_code("/home/me/h/src/shell.src") // extend map

get_import_paths = function(code)
	lines = code.split(char(10))

	r = []
	for l in lines
		if l.indexOf("import_code" + "(""") != null then r.push(l.split("""")[1])
	end for

	return r
end function

check_sum_source = function(code)
	comp = get_shell.host_computer
	codes = [code]
	
	for s in get_import_paths(code)
		codes.push comp.File(s).get_content
	end for
	
	return md5(codes.join(""))
end function

comp = get_shell.host_computer

print "setup hacking script"
comp.File("/home/me/h/src/tableAttack.src").copy(home_dir + "/Config", "tableAttack.src")
comp.File("/home/me/h/src/rserverInstaller.src").copy(home_dir + "/Config", "rserverInstaller.src")
//get_shell.host_computer.touch(home_dir + "/Config", "emptyLog")

print "compiling cli tools"
comp.create_folder(home_dir, "vegaTools")

while true
	comp.touch(home_dir, ".vega_watch")
	watch_file = comp.File(home_dir + "/.vega_watch")

	watch_data = {}
	f = function(o)
		return o.split("=")
	end function
	if watch_file.get_content.len > 1 then watch_data = watch_file.get_content.split(char(10)).map(@f).to_map

	for f in comp.File("/home/me/h/cli").get_files
		if watch_data.hasIndex(f.name) == false then watch_data[f.name] = check_sum_source(f.get_content)
	
		compiled_script = comp.File(home_dir + "/vegaTools/" + f.name[:-4])

		if watch_data[f.name] != check_sum_source(f.get_content) or compiled_script == null then
			print "compiling " + f.name
			f.copy(home_dir + "/vegaTools", f.name)
			b = get_shell.build(home_dir + "/vegaTools/" + f.name, home_dir + "/vegaTools")
			if b.len > 0 then print(f.name + " error: <color=red>" + b + "</color>")
			comp.File(home_dir + "/vegaTools/" + f.name).delete
			watch_data[f.name] = check_sum_source(f.get_content)
		end if
	end for

	f = function(o)
		return o[0] + "=" + o[1]
	end function
	watch_file.set_content watch_data.to_list.map(@f).join(char(10))

	if params.hasIndex(0) == false or params[0] != "-w" then break
end while

// get bounce vulnerable router lib
print("getting bounce vulnerable router lib")
Machine.metaxploit = include_lib("/lib/metaxploit.so")
Scan.metaxploit = include_lib("/lib/metaxploit.so")
if comp.File(home_dir + "/Config/routerBouncerLib/kernel_router.so") == null then
	while true
		machine = new Machine
		machine.init(rnd_ip)
		machine.router_service.set_exploits
		
		shell = machine.router_service.quick_root_shell
		
		if typeof(shell) != "shell" then continue
		
		if machine.router_service.get_bounce_exploits.len > 0 then	
			get_shell.host_computer.create_folder(home_dir + "/Config", "routerBouncerLib")
			shell.scp("/lib/kernel_router.so", home_dir + "/Config/routerBouncerLib", get_shell)
			break
		end if
	end while
end if

Disk.init(home_dir + "/Config", "passwords")

// setup passwords db
if Disk.read_chars.len > 0 then exit

if(Disk.blobs.len > 1) then exit("password generation setup already completed")

PasswordGenerator.init(PASSWORDS)
print "generating passwords, it will take a while"
HASH_TABLE=PasswordGenerator.AllPasswords
print "done"

print "parsing passwords obj"
f = function(o)
	return o[1]
end function
pass_list = HASH_TABLE.to_list.map(@f)	
print "done"

print "writing to disk"
Disk.write(pass_list.join(char(10)))
print "done"